Excel | SUMIFS와 COUNTIFS 함수

 

 SUMIFS 함수란?

SUMIFS 함수는 여러 조건을 만족하는 데이터들의 합계를 구할 때 사용하는 함수입니다.

=SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

sum_range	합계를 구할 값들의 범위
criteria_range1	첫 번째 조건을 적용할 범위
criteria1	첫 번째 조건
criteria_range2, criteria2	(선택) 추가 조건들

 

=SUMIFS(Donations[Donation], Donations[Donation], ">="&Overview!$C$7, Donations[Payment], Overview!B9)

SUMIFS	여러 조건을 만족하는 값들의 합을 구하는 함수
Donations[Donation]	합계를 구할 범위(sum_range) — 기부금액
Donations[Donation], ">="&Overview!$C$7	첫 번째 조건:기부금액이 Overview 시트의 C7셀 값보다 크거나 같을 것
Donations[Payment], Overview!B9	두 번째 조건:결제 방법이 Overview 시트의 B9셀 값과 같을 것

=SUMIFS(Donations[Donation],
        Donations[Payment], "<>"&"Online",
        Donations[Date], ">="&Overview!C2,
        Donations[Date], "<="&EOMONTH(Overview!C2,0))

SUMIFS	여러 조건을 만족하는 값들의 합을 구하는 함수
Donations[Donation]	합계 범위 — 기부금액
Donations[Payment], "<>"&"Online"	조건 1:Payment가 “Online”이 아닌 경우
Donations[Date], ">="&Overview!C2	조건 2:Date가 Overview 시트의 C2셀 이후 또는 같은 날
Donations[Date], "<="&EOMONTH(Overview!C2,0)	조건 3:Date가 C2 셀의 같은 달의 마지막 날 이하

COUNTIFS 함수란?

COUNTIFS 함수는 여러 조건을 만족하는 데이터들의 개수를 셀 때 사용하는 함수입니다.

=COUNTIFS(criteria_range1, criteria1, [criteria_range2, criteria2], ...)

criteria_range1	첫 번째 조건을 적용할 범위
criteria1	첫 번째 조건
criteria_range2, criteria2	(선택) 추가 조건들

=COUNTIFS(Donations[Payment], Overview!B9,
          Donations[Donation], ">="&Overview!$C$7)

COUNTIFS	여러 조건을 만족하는 행의 개수를 세는 함수
Donations[Payment], Overview!B9	조건 1:Payment가 Overview!B9 셀과 같은 경우
Donations[Donation], ">="&Overview!$C$7	조건 2:Donation 금액이 Overview!$C$7 셀 값 이상인 경우